Das Portal zum Thema Excel-Formeln

Anhand vorgegebener Polynom-Koeffizienten willst Du zu X-Werten die Y-Werte berechnen.

Beispiel, Polynom 4.Ordnung, y=a*x^4+b*x^3+c*x^2+d*x+e

A               B               C               D               E        1 X-Werte  Y-Werte    Koeffiz.  Wert   2 1  3    e  5   3 2  9    d  -4   4 3  47    c  3   5 4  165    b  -2   6 5  435    a  1

Lösung

In A2:A5 stehen die X-Werte

In D2:D6 stehen die Polynom_Koeffizienten mit Werten
Das Polynom im Beispiel lautet also x^4-2*x^3+3*x^2-4*x+5

es gibt drei Möglichkeiten, die Y-Werte zu berechen:

1. "zu Fuß"
in B2 steht:=$E$2*A2^0+$E$3*A2^1+$E$4*A2^2+$E$5*A2^3+$E$6*A2^4 (kopieren bis B6)

dies ist sehr unflexibel, wenn sich die Ordnungszahl erhöht.

2. Arrayformel
in B2 steht: { =SUMME(E$2:E$6*A2^({0;1;2;3;4})) } (kopieren bis B6)

3. NBW
in B2 steht:=NBW(1/(A2)-1;E$2:E$6)/A2 (kopieren bis B6)

NBW ist eigentlich ein Funktion der Finanzmathematik, die Zahlungsreihen in der Form

=Z1/(1+zins)+Z2/(1+zins)^2+Z3/(1+zins)^3+...+Zn/(1+zins)^n abzinst.

Wie man sieht kann NBW aber zu jedem Polynom beliebigen Grades die Y-Werte berechnen.

Sie liefert allerdings gelegentlich minimale Rundungsfehler, im Beispiel statt 47 47,0000000000001

ACHTUNG:
In allen 3 Formeln wird bei X=0 ein Fehler geliefert. Um das zu vermeiden schreibe

=WENN(A1=0;$E$2;Formel)

da der Y-Achsenschnittpunkt dem Koeffizienten e in E2 entspricht

Erläuterung

Was hat die Finanzmathematische Funktion
NBW mit Polynomen zu tun ?

eine Zahlungsreihe der FI-Math. über n-Perioden ist eigentlich nichts anderes als ein Polynom n-ter Ordnung

Du hast n Zahlungen a,b,c,d,e,...,n in n Perioden.

Willst Du den Barwert ausrechnen mußt Du jede Zahlung mit dem Faktor 1/(1+zinssatz) multiplizieren(abzinsen) und zwar a 1mal b 2mal und so weiter:

NBW = a*1/(1+zinssatz)^1+b*1/(1+zinssatz)^2+c*1/(1+zinssatz)^3+d*1/(1+zinssatz)^4+e*1/(1+zinssatz)^5+...+n*1/(1+zinssatz)^n

Genau so macht das die Excel-Funktion NBW.

Setzt Du nun 1/(1+zinssatz)=x

ergibt sich
NBW=a*x+b*x^2+c*x^3+d*x^4+e*x^5+...+n*x^n
teilt man die Gleichung durch x ergibt sich
NBW/x=a+b*x+c*x^2+d*x^3+e*x^4+...+n*x^(n-1)
und bei NBW/x = y.
ergibt sich das Polynom in allgemeiner Form
y = a+b*x+c*x^2+d*x^3+e*x^4+...+n*x^(n-1)

In das erste Argument von NBW gibt man den Zinssatz ein. Nirgendwo ist aber vorgeschrieben, dass er zwischen 0% und 100% liegt.
Die Formel funktioniert nämlich für alle Werte.

Löst man nun 1/(1+zinssatz)=x nach zinssatz (i) auf ergibt sich:
i=1/x-1

Will man nun den Y-Wert für x=-15 ausrechnen, gibt man als Zinssatz
1/x-1=-106,666667%

das macht natürlich finanzmathematisch keinen Sinn, funktioniert aber trotzdem.